<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package URI::gopher;  # &lt;draft-murali-url-gopher&gt;, Dec 4, 1996

use strict;
use warnings;

our $VERSION = '1.76';

use parent 'URI::_server';

use URI::Escape qw(uri_unescape);

#  A Gopher URL follows the common internet scheme syntax as defined in 
#  section 4.3 of [RFC-URL-SYNTAX]:
#
#        gopher://&lt;host&gt;[:&lt;port&gt;]/&lt;gopher-path&gt;
#
#  where
#
#        &lt;gopher-path&gt; :=  &lt;gopher-type&gt;&lt;selector&gt; | 
#                          &lt;gopher-type&gt;&lt;selector&gt;%09&lt;search&gt; |
#                          &lt;gopher-type&gt;&lt;selector&gt;%09&lt;search&gt;%09&lt;gopher+_string&gt;
#
#        &lt;gopher-type&gt; := '0' | '1' | '2' | '3' | '4' | '5' | '6' | '7'
#                         '8' | '9' | '+' | 'I' | 'g' | 'T'
#
#        &lt;selector&gt;    := *pchar     Refer to RFC 1808 [4]
#        &lt;search&gt;      := *pchar
#        &lt;gopher+_string&gt; := *uchar  Refer to RFC 1738 [3]
#        
#  If the optional port is omitted, the port defaults to 70. 

sub default_port { 70 }

sub _gopher_type
{
    my $self = shift;
    my $path = $self-&gt;path_query;
    $path =~ s,^/,,;
    my $gtype = $1 if $path =~ s/^(.)//s;
    if (@_) {
	my $new_type = shift;
	if (defined($new_type)) {
	    Carp::croak("Bad gopher type '$new_type'")
               unless length($new_type) == 1;
	    substr($path, 0, 0) = $new_type;
	    $self-&gt;path_query($path);
	} else {
	    Carp::croak("Can't delete gopher type when selector is present")
		if length($path);
	    $self-&gt;path_query(undef);
	}
    }
    return $gtype;
}

sub gopher_type
{
    my $self = shift;
    my $gtype = $self-&gt;_gopher_type(@_);
    $gtype = "1" unless defined $gtype;
    $gtype;
}

sub gtype { goto &amp;gopher_type }  # URI::URL compatibility

sub selector { shift-&gt;_gfield(0, @_) }
sub search   { shift-&gt;_gfield(1, @_) }
sub string   { shift-&gt;_gfield(2, @_) }

sub _gfield
{
    my $self = shift;
    my $fno  = shift;
    my $path = $self-&gt;path_query;

    # not according to spec., but many popular browsers accept
    # gopher URLs with a '?' before the search string.
    $path =~ s/\?/\t/;
    $path = uri_unescape($path);
    $path =~ s,^/,,;
    my $gtype = $1 if $path =~ s,^(.),,s;
    my @path = split(/\t/, $path, 3);
    if (@_) {
	# modify
	my $new = shift;
	$path[$fno] = $new;
	pop(@path) while @path &amp;&amp; !defined($path[-1]);
	for (@path) { $_="" unless defined }
	$path = $gtype;
	$path = "1" unless defined $path;
	$path .= join("\t", @path);
	$self-&gt;path_query($path);
    }
    $path[$fno];
}

1;
</pre></body></html>