<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package HTML::Form;

use strict;
use URI;
use Carp ();
use Encode ();

use vars qw($VERSION);
our $VERSION = '6.07';

my %form_tags = map {$_ =&gt; 1} qw(input textarea button select option);

my %type2class = (
 text     =&gt; "TextInput",
 password =&gt; "TextInput",
 hidden   =&gt; "TextInput",
 textarea =&gt; "TextInput",

 "reset"  =&gt; "IgnoreInput",

 radio    =&gt; "ListInput",
 checkbox =&gt; "ListInput",
 option   =&gt; "ListInput",

 button   =&gt; "SubmitInput",
 submit   =&gt; "SubmitInput",
 image    =&gt; "ImageInput",
 file     =&gt; "FileInput",

 keygen   =&gt; "KeygenInput",
);

# The new HTML5 input types
%type2class = (%type2class, map { $_ =&gt; 'TextInput' } qw(
    tel search url email
    datetime date month week time datetime-local
    number range color
));

# ABSTRACT: Class that represents an HTML form element


sub parse
{
    my $class = shift;
    my $html = shift;
    unshift(@_, "base") if @_ == 1;
    my %opt = @_;

    require HTML::TokeParser;
    my $p = HTML::TokeParser-&gt;new(ref($html) ? $html-&gt;decoded_content(ref =&gt; 1) : \$html);
    die "Failed to create HTML::TokeParser object" unless $p;

    my $base_uri = delete $opt{base};
    my $charset = delete $opt{charset};
    my $strict = delete $opt{strict};
    my $verbose = delete $opt{verbose};

    if ($^W) {
	Carp::carp("Unrecognized option $_ in HTML::Form-&gt;parse") for sort keys %opt;
    }

    unless (defined $base_uri) {
	if (ref($html)) {
	    $base_uri = $html-&gt;base;
	}
	else {
	    Carp::croak("HTML::Form::parse: No \$base_uri provided");
	}
    }
    unless (defined $charset) {
	if (ref($html) and $html-&gt;can("content_charset")) {
	    $charset = $html-&gt;content_charset;
	}
	unless ($charset) {
	    $charset = "UTF-8";
	}
    }

    my @forms;
    my $f;  # current form

    my %openselect; # index to the open instance of a select

    while (my $t = $p-&gt;get_tag) {
	my($tag,$attr) = @$t;
	if ($tag eq "form") {
	    my $action = delete $attr-&gt;{'action'};
	    $action = "" unless defined $action;
	    $action = URI-&gt;new_abs($action, $base_uri);
	    $f = $class-&gt;new($attr-&gt;{'method'},
			     $action,
			     $attr-&gt;{'enctype'});
            $f-&gt;accept_charset($attr-&gt;{'accept-charset'}) if $attr-&gt;{'accept-charset'};
	    $f-&gt;{default_charset} = $charset;
	    $f-&gt;{attr} = $attr;
	    $f-&gt;strict(1) if $strict;
            %openselect = ();
	    push(@forms, $f);
	    my(%labels, $current_label);
	    while (my $t = $p-&gt;get_tag) {
		my($tag, $attr) = @$t;
		last if $tag eq "/form";

		if ($tag ne 'textarea') {
		    # if we are inside a label tag, then keep
		    # appending any text to the current label
		    if(defined $current_label) {
		        $current_label = join " ",
		            grep { defined and length }
		            $current_label,
		            $p-&gt;get_phrase;
		    }
		}

		if ($tag eq "input") {
		    $attr-&gt;{value_name} =
		        exists $attr-&gt;{id} &amp;&amp; exists $labels{$attr-&gt;{id}} ? $labels{$attr-&gt;{id}} :
			defined $current_label                            ?  $current_label      :
		        $p-&gt;get_phrase;
		}

		if ($tag eq "label") {
		    $current_label = $p-&gt;get_phrase;
		    $labels{ $attr-&gt;{for} } = $current_label
		        if exists $attr-&gt;{for};
		}
		elsif ($tag eq "/label") {
		    $current_label = undef;
		}
		elsif ($tag eq "input") {
		    my $type = delete $attr-&gt;{type} || "text";
		    $f-&gt;push_input($type, $attr, $verbose);
		}
                elsif ($tag eq "button") {
                    my $type = delete $attr-&gt;{type} || "submit";
                    $f-&gt;push_input($type, $attr, $verbose);
                }
		elsif ($tag eq "textarea") {
		    $attr-&gt;{textarea_value} = $attr-&gt;{value}
		        if exists $attr-&gt;{value};
		    my $text = $p-&gt;get_text("/textarea");
		    $attr-&gt;{value} = $text;
		    $f-&gt;push_input("textarea", $attr, $verbose);
		}
		elsif ($tag eq "select") {
		    # rename attributes reserved to come for the option tag
		    for ("value", "value_name") {
			$attr-&gt;{"select_$_"} = delete $attr-&gt;{$_}
			    if exists $attr-&gt;{$_};
		    }
		    # count this new select option separately
		    my $name = $attr-&gt;{name};
		    $name = "" unless defined $name;
		    $openselect{$name}++;

		    while ($t = $p-&gt;get_tag) {
			my $tag = shift @$t;
			last if $tag eq "/select";
			next if $tag =~ m,/?optgroup,;
			next if $tag eq "/option";
			if ($tag eq "option") {
			    my %a = %{$t-&gt;[0]};
			    # rename keys so they don't clash with %attr
			    for (keys %a) {
				next if $_ eq "value";
				$a{"option_$_"} = delete $a{$_};
			    }
			    while (my($k,$v) = each %$attr) {
				$a{$k} = $v;
			    }
			    $a{value_name} = $p-&gt;get_trimmed_text;
			    $a{value} = delete $a{value_name}
				unless defined $a{value};
			    $a{idx} = $openselect{$name};
			    $f-&gt;push_input("option", \%a, $verbose);
			}
			else {
			    warn("Bad &lt;select&gt; tag '$tag' in $base_uri\n") if $verbose;
			    if ($tag eq "/form" ||
				$tag eq "input" ||
				$tag eq "textarea" ||
				$tag eq "select" ||
				$tag eq "keygen")
			    {
				# MSIE implicitly terminates the &lt;select&gt; here, so we
				# try to do the same.  Actually the MSIE behaviour
				# appears really strange:  &lt;input&gt; and &lt;textarea&gt;
				# do implicitly close, but not &lt;select&gt;, &lt;keygen&gt; or
				# &lt;/form&gt;.
				my $type = ($tag =~ s,^/,,) ? "E" : "S";
				$p-&gt;unget_token([$type, $tag, @$t]);
				last;
			    }
			}
		    }
		}
		elsif ($tag eq "keygen") {
		    $f-&gt;push_input("keygen", $attr, $verbose);
		}
	    }
	}
	elsif ($form_tags{$tag}) {
	    warn("&lt;$tag&gt; outside &lt;form&gt; in $base_uri\n") if $verbose;
	}
    }
    for (@forms) {
	$_-&gt;fixup;
    }

    wantarray ? @forms : $forms[0];
}

sub new {
    my $class = shift;
    my $self = bless {}, $class;
    $self-&gt;{method} = uc(shift  || "GET");
    $self-&gt;{action} = shift  || Carp::croak("No action defined");
    $self-&gt;{enctype} = lc(shift || "application/x-www-form-urlencoded");
    $self-&gt;{accept_charset} = "UNKNOWN";
    $self-&gt;{default_charset} = "UTF-8";
    $self-&gt;{inputs} = [@_];
    $self;
}


sub push_input
{
    my($self, $type, $attr, $verbose) = @_;
    $type = lc $type;
    my $class = $type2class{$type};
    unless ($class) {
	Carp::carp("Unknown input type '$type'") if $verbose;
	$class = "TextInput";
    }
    $class = "HTML::Form::$class";
    my @extra;
    push(@extra, readonly =&gt; 1) if $type eq "hidden";
    push(@extra, strict =&gt; 1) if $self-&gt;{strict};
    if ($type eq "file" &amp;&amp; exists $attr-&gt;{value}) {
	# it's not safe to trust the value set by the server
	# the user always needs to explicitly set the names of files to upload
	$attr-&gt;{orig_value} = delete $attr-&gt;{value};
    }
    delete $attr-&gt;{type}; # don't confuse the type argument
    my $input = $class-&gt;new(type =&gt; $type, %$attr, @extra);
    $input-&gt;add_to_form($self);
}



BEGIN {
    # Set up some accessors
    for (qw(method action enctype accept_charset)) {
	my $m = $_;
	no strict 'refs';
	*{$m} = sub {
	    my $self = shift;
	    my $old = $self-&gt;{$m};
	    $self-&gt;{$m} = shift if @_;
	    $old;
	};
    }
    *uri = \&amp;action;  # alias
}


sub attr {
    my $self = shift;
    my $name = shift;
    return undef unless defined $name;

    my $old = $self-&gt;{attr}{$name};
    $self-&gt;{attr}{$name} = shift if @_;
    return $old;
}


sub strict {
    my $self = shift;
    my $old = $self-&gt;{strict};
    if (@_) {
	$self-&gt;{strict} = shift;
	for my $input (@{$self-&gt;{inputs}}) {
	    $input-&gt;strict($self-&gt;{strict});
	}
    }
    return $old;
}



sub inputs
{
    my $self = shift;
    @{$self-&gt;{'inputs'}};
}



sub find_input
{
    my($self, $name, $type, $no) = @_;
    die "Invalid index $no"
        if defined $no &amp;&amp; $no &lt; 1;
    if (wantarray) {
        warn "find_input called in list context with index specified\n"
            if defined $no;
	my @res;
	my $c;
	for (@{$self-&gt;{'inputs'}}) {
	    next if defined($name) &amp;&amp; !$_-&gt;selected($name);
	    next if $type &amp;&amp; $type ne $_-&gt;{type};
	    $c++;
	    next if $no &amp;&amp; $no != $c;
	    push(@res, $_);
	}
	return @res;

    }
    else {
	$no ||= 1;
	for (@{$self-&gt;{'inputs'}}) {
	    next if defined($name) &amp;&amp; !$_-&gt;selected($name);
	    next if $type &amp;&amp; $type ne $_-&gt;{type};
	    next if --$no;
	    return $_;
	}
	return undef;
    }
}

sub fixup
{
    my $self = shift;
    for (@{$self-&gt;{'inputs'}}) {
	$_-&gt;fixup;
    }
}



sub value
{
    my $self = shift;
    my $key  = shift;
    my $input = $self-&gt;find_input($key);
    unless ($input) {
	Carp::croak("No such field '$key'") if $self-&gt;{strict};
	return undef unless @_;
	$input = $self-&gt;push_input("text", { name =&gt; $key, value =&gt; "" });
    }
    local $Carp::CarpLevel = 1;
    $input-&gt;value(@_);
}


sub param {
    my $self = shift;
    if (@_) {
        my $name = shift;
        my @inputs;
        for ($self-&gt;inputs) {
            my $n = $_-&gt;name;
            next if !defined($n) || $n ne $name;
            push(@inputs, $_);
        }

        if (@_) {
            # set
            die "No '$name' parameter exists" unless @inputs;
	    my @v = @_;
	    @v = @{$v[0]} if @v == 1 &amp;&amp; ref($v[0]);
            while (@v) {
                my $v = shift @v;
                my $err;
                for my $i (0 .. @inputs-1) {
                    eval {
                        $inputs[$i]-&gt;value($v);
                    };
                    unless ($@) {
                        undef($err);
                        splice(@inputs, $i, 1);
                        last;
                    }
                    $err ||= $@;
                }
                die $err if $err;
            }

	    # the rest of the input should be cleared
	    for (@inputs) {
		$_-&gt;value(undef);
	    }
        }
        else {
            # get
            my @v;
            for (@inputs) {
		if (defined(my $v = $_-&gt;value)) {
		    push(@v, $v);
		}
            }
            return wantarray ? @v : $v[0];
        }
    }
    else {
        # list parameter names
        my @n;
        my %seen;
        for ($self-&gt;inputs) {
            my $n = $_-&gt;name;
            next if !defined($n) || $seen{$n}++;
            push(@n, $n);
        }
        return @n;
    }
}



sub try_others
{
    my($self, $cb) = @_;
    my @try;
    for (@{$self-&gt;{'inputs'}}) {
	my @not_tried_yet = $_-&gt;other_possible_values;
	next unless @not_tried_yet;
	push(@try, [\@not_tried_yet, $_]);
    }
    return unless @try;
    $self-&gt;_try($cb, \@try, 0);
}

sub _try
{
    my($self, $cb, $try, $i) = @_;
    for (@{$try-&gt;[$i][0]}) {
	$try-&gt;[$i][1]-&gt;value($_);
	&amp;$cb($self);
	$self-&gt;_try($cb, $try, $i+1) if $i+1 &lt; @$try;
    }
}



sub make_request
{
    my $self = shift;
    my $method  = uc $self-&gt;{'method'};
    my $uri     = $self-&gt;{'action'};
    my $enctype = $self-&gt;{'enctype'};
    my @form    = $self-&gt;form;

    my $charset = $self-&gt;accept_charset eq "UNKNOWN" ? $self-&gt;{default_charset} : $self-&gt;accept_charset;
    foreach my $fi (@form) {
	$fi = Encode::encode($charset, $fi) unless ref($fi);
    }

    if ($method eq "GET") {
	require HTTP::Request;
	$uri = URI-&gt;new($uri, "http");
	$uri-&gt;query_form(@form);
	return HTTP::Request-&gt;new(GET =&gt; $uri);
    }
    elsif ($method eq "POST") {
	require HTTP::Request::Common;
	return HTTP::Request::Common::POST($uri, \@form,
					   Content_Type =&gt; $enctype);
    }
    else {
	Carp::croak("Unknown method '$method'");
    }
}



sub click
{
    my $self = shift;
    my $name;
    $name = shift if (@_ % 2) == 1;  # odd number of arguments

    # try to find first submit button to activate
    for (@{$self-&gt;{'inputs'}}) {
        next unless $_-&gt;can("click");
        next if $name &amp;&amp; !$_-&gt;selected($name);
	next if $_-&gt;disabled;
	return $_-&gt;click($self, @_);
    }
    Carp::croak("No clickable input with name $name") if $name;
    $self-&gt;make_request;
}



sub form
{
    my $self = shift;
    map { $_-&gt;form_name_value($self) } @{$self-&gt;{'inputs'}};
}



sub dump
{
    my $self = shift;
    my $method  = $self-&gt;{'method'};
    my $uri     = $self-&gt;{'action'};
    my $enctype = $self-&gt;{'enctype'};
    my $dump = "$method $uri";
    $dump .= " ($enctype)"
	if $enctype ne "application/x-www-form-urlencoded";
    $dump .= " [$self-&gt;{attr}{name}]"
    	if exists $self-&gt;{attr}{name};
    $dump .= "\n";
    for ($self-&gt;inputs) {
	$dump .= "  " . $_-&gt;dump . "\n";
    }
    print STDERR $dump unless defined wantarray;
    $dump;
}


#---------------------------------------------------
package HTML::Form::Input;


sub new
{
    my $class = shift;
    my $self = bless {@_}, $class;
    $self;
}

sub add_to_form
{
    my($self, $form) = @_;
    push(@{$form-&gt;{'inputs'}}, $self);
    $self;
}

sub strict {
    my $self = shift;
    my $old = $self-&gt;{strict};
    if (@_) {
	$self-&gt;{strict} = shift;
    }
    $old;
}

sub fixup {}



sub type
{
    shift-&gt;{type};
}


sub name
{
    my $self = shift;
    my $old = $self-&gt;{name};
    $self-&gt;{name} = shift if @_;
    $old;
}

sub id
{
    my $self = shift;
    my $old = $self-&gt;{id};
    $self-&gt;{id} = shift if @_;
    $old;
}

sub class
{
    my $self = shift;
    my $old = $self-&gt;{class};
    $self-&gt;{class} = shift if @_;
    $old;
}

sub selected {
    my($self, $sel) = @_;
    return undef unless defined $sel;
    my $attr =
        $sel =~ s/^\^// ? "name"  :
        $sel =~ s/^#//  ? "id"    :
        $sel =~ s/^\.// ? "class" :
	                  "name";
    return 0 unless defined $self-&gt;{$attr};
    return $self-&gt;{$attr} eq $sel;
}

sub value
{
    my $self = shift;
    my $old = $self-&gt;{value};
    $self-&gt;{value} = shift if @_;
    $old;
}

sub autocomplete
{
    my $self = shift;
    my $old = $self-&gt;{autocomplete};
    $self-&gt;{autocomplete} = shift if @_;
    $old;
}


sub possible_values
{
    return;
}


sub other_possible_values
{
    return;
}


sub value_names {
    return
}


sub readonly {
    my $self = shift;
    my $old = $self-&gt;{readonly};
    $self-&gt;{readonly} = shift if @_;
    $old;
}


sub disabled {
    my $self = shift;
    my $old = $self-&gt;{disabled};
    $self-&gt;{disabled} = shift if @_;
    $old;
}


sub form_name_value
{
    my $self = shift;
    my $name = $self-&gt;{'name'};
    return unless defined $name;
    return if $self-&gt;disabled;
    my $value = $self-&gt;value;
    return unless defined $value;
    return ($name =&gt; $value);
}

sub dump
{
    my $self = shift;
    my $name = $self-&gt;name;
    $name = "&lt;NONAME&gt;" unless defined $name;
    my $value = $self-&gt;value;
    $value = "&lt;UNDEF&gt;" unless defined $value;
    my $dump = "$name=$value";

    my $type = $self-&gt;type;

    $type .= " disabled" if $self-&gt;disabled;
    $type .= " readonly" if $self-&gt;readonly;
    return sprintf "%-30s %s", $dump, "($type)" unless $self-&gt;{menu};

    my @menu;
    my $i = 0;
    for (@{$self-&gt;{menu}}) {
	my $opt = $_-&gt;{value};
	$opt = "&lt;UNDEF&gt;" unless defined $opt;
	$opt .= "/$_-&gt;{name}"
	    if defined $_-&gt;{name} &amp;&amp; length $_-&gt;{name} &amp;&amp; $_-&gt;{name} ne $opt;
	substr($opt,0,0) = "-" if $_-&gt;{disabled};
	if (exists $self-&gt;{current} &amp;&amp; $self-&gt;{current} == $i) {
	    substr($opt,0,0) = "!" unless $_-&gt;{seen};
	    substr($opt,0,0) = "*";
	}
	else {
	    substr($opt,0,0) = ":" if $_-&gt;{seen};
	}
	push(@menu, $opt);
	$i++;
    }

    return sprintf "%-30s %-10s %s", $dump, "($type)", "[" . join("|", @menu) . "]";
}


#---------------------------------------------------
package HTML::Form::TextInput;
@HTML::Form::TextInput::ISA=qw(HTML::Form::Input);

#input/text
#input/password
#input/hidden
#textarea

sub value
{
    my $self = shift;
    my $old = $self-&gt;{value};
    $old = "" unless defined $old;
    if (@_) {
        Carp::croak("Input '$self-&gt;{name}' is readonly")
	    if $self-&gt;{strict} &amp;&amp; $self-&gt;{readonly};
        my $new = shift;
        my $n = exists $self-&gt;{maxlength} ? $self-&gt;{maxlength} : undef;
        Carp::croak("Input '$self-&gt;{name}' has maxlength '$n'")
	    if $self-&gt;{strict} &amp;&amp; defined($n) &amp;&amp; defined($new) &amp;&amp; length($new) &gt; $n;
	$self-&gt;{value} = $new;
    }
    $old;
}

#---------------------------------------------------
package HTML::Form::IgnoreInput;
@HTML::Form::IgnoreInput::ISA=qw(HTML::Form::Input);

#input/button
#input/reset

sub value { return }


#---------------------------------------------------
package HTML::Form::ListInput;
@HTML::Form::ListInput::ISA=qw(HTML::Form::Input);

#select/option   (val1, val2, ....)
#input/radio     (undef, val1, val2,...)
#input/checkbox  (undef, value)
#select-multiple/option (undef, value)

sub new
{
    my $class = shift;
    my $self = $class-&gt;SUPER::new(@_);

    my $value = delete $self-&gt;{value};
    my $value_name = delete $self-&gt;{value_name};
    my $type = $self-&gt;{type};

    if ($type eq "checkbox") {
	$value = "on" unless defined $value;
	$self-&gt;{menu} = [
	    { value =&gt; undef, name =&gt; "off", },
            { value =&gt; $value, name =&gt; $value_name, },
        ];
	$self-&gt;{current} = (delete $self-&gt;{checked}) ? 1 : 0;
	;
    }
    else {
	$self-&gt;{option_disabled}++
	    if $type eq "radio" &amp;&amp; delete $self-&gt;{disabled};
	$self-&gt;{menu} = [
            {value =&gt; $value, name =&gt; $value_name},
        ];
	my $checked = $self-&gt;{checked} || $self-&gt;{option_selected};
	delete $self-&gt;{checked};
	delete $self-&gt;{option_selected};
	if (exists $self-&gt;{multiple}) {
	    unshift(@{$self-&gt;{menu}}, { value =&gt; undef, name =&gt; "off"});
	    $self-&gt;{current} = $checked ? 1 : 0;
	}
	else {
	    $self-&gt;{current} = 0 if $checked;
	}
    }
    $self;
}

sub add_to_form
{
    my($self, $form) = @_;
    my $type = $self-&gt;type;

    return $self-&gt;SUPER::add_to_form($form)
	if $type eq "checkbox";

    if ($type eq "option" &amp;&amp; exists $self-&gt;{multiple}) {
	$self-&gt;{disabled} ||= delete $self-&gt;{option_disabled};
	return $self-&gt;SUPER::add_to_form($form);
    }

    die "Assert" if @{$self-&gt;{menu}} != 1;
    my $m = $self-&gt;{menu}[0];
    $m-&gt;{disabled}++ if delete $self-&gt;{option_disabled};

    my $prev = $form-&gt;find_input($self-&gt;{name}, $self-&gt;{type}, $self-&gt;{idx});
    return $self-&gt;SUPER::add_to_form($form) unless $prev;

    # merge menus
    $prev-&gt;{current} = @{$prev-&gt;{menu}} if exists $self-&gt;{current};
    push(@{$prev-&gt;{menu}}, $m);
}

sub fixup
{
    my $self = shift;
    if ($self-&gt;{type} eq "option" &amp;&amp; !(exists $self-&gt;{current})) {
	$self-&gt;{current} = 0;
    }
    $self-&gt;{menu}[$self-&gt;{current}]{seen}++ if exists $self-&gt;{current};
}

sub disabled
{
    my $self = shift;
    my $type = $self-&gt;type;

    my $old = $self-&gt;{disabled} || _menu_all_disabled(@{$self-&gt;{menu}});
    if (@_) {
	my $v = shift;
	$self-&gt;{disabled} = $v;
        for (@{$self-&gt;{menu}}) {
            $_-&gt;{disabled} = $v;
        }
    }
    return $old;
}

sub _menu_all_disabled {
    for (@_) {
	return 0 unless $_-&gt;{disabled};
    }
    return 1;
}

sub value
{
    my $self = shift;
    my $old;
    $old = $self-&gt;{menu}[$self-&gt;{current}]{value} if exists $self-&gt;{current};
    $old = $self-&gt;{value} if exists $self-&gt;{value};
    if (@_) {
	my $i = 0;
	my $val = shift;
	my $cur;
	my $disabled;
	for (@{$self-&gt;{menu}}) {
	    if ((defined($val) &amp;&amp; defined($_-&gt;{value}) &amp;&amp; $val eq $_-&gt;{value}) ||
		(!defined($val) &amp;&amp; !defined($_-&gt;{value}))
	       )
	    {
		$cur = $i;
		$disabled = $_-&gt;{disabled};
		last unless $disabled;
	    }
	    $i++;
	}
	if (!(defined $cur) || $disabled) {
	    if (defined $val) {
		# try to search among the alternative names as well
		my $i = 0;
		my $cur_ignorecase;
		my $lc_val = lc($val);
		for (@{$self-&gt;{menu}}) {
		    if (defined $_-&gt;{name}) {
			if ($val eq $_-&gt;{name}) {
			    $disabled = $_-&gt;{disabled};
			    $cur = $i;
			    last unless $disabled;
			}
			if (!defined($cur_ignorecase) &amp;&amp; $lc_val eq lc($_-&gt;{name})) {
			    $cur_ignorecase = $i;
			}
		    }
		    $i++;
		}
		unless (defined $cur) {
		    $cur = $cur_ignorecase;
		    if (defined $cur) {
			$disabled = $self-&gt;{menu}[$cur]{disabled};
		    }
		    elsif ($self-&gt;{strict}) {
			my $n = $self-&gt;name;
		        Carp::croak("Illegal value '$val' for field '$n'");
		    }
		}
	    }
	    elsif ($self-&gt;{strict}) {
		my $n = $self-&gt;name;
	        Carp::croak("The '$n' field can't be unchecked");
	    }
	}
	if ($self-&gt;{strict} &amp;&amp; $disabled) {
	    my $n = $self-&gt;name;
	    Carp::croak("The value '$val' has been disabled for field '$n'");
	}
	if (defined $cur) {
	    $self-&gt;{current} = $cur;
	    $self-&gt;{menu}[$cur]{seen}++;
	    delete $self-&gt;{value};
	}
	else {
	    $self-&gt;{value} = $val;
	    delete $self-&gt;{current};
	}
    }
    $old;
}


sub check
{
    my $self = shift;
    $self-&gt;{current} = 1;
    $self-&gt;{menu}[1]{seen}++;
}

sub possible_values
{
    my $self = shift;
    map $_-&gt;{value}, grep !$_-&gt;{disabled}, @{$self-&gt;{menu}};
}

sub other_possible_values
{
    my $self = shift;
    map $_-&gt;{value}, grep !$_-&gt;{seen} &amp;&amp; !$_-&gt;{disabled}, @{$self-&gt;{menu}};
}

sub value_names {
    my $self = shift;
    my @names;
    for (@{$self-&gt;{menu}}) {
	my $n = $_-&gt;{name};
	$n = $_-&gt;{value} unless defined $n;
	push(@names, $n);
    }
    @names;
}


#---------------------------------------------------
package HTML::Form::SubmitInput;
@HTML::Form::SubmitInput::ISA=qw(HTML::Form::Input);

#input/image
#input/submit


sub click
{
    my($self,$form,$x,$y) = @_;
    for ($x, $y) { $_ = 1 unless defined; }
    local($self-&gt;{clicked}) = [$x,$y];
    return $form-&gt;make_request;
}

sub form_name_value
{
    my $self = shift;
    return unless $self-&gt;{clicked};
    return $self-&gt;SUPER::form_name_value(@_);
}


#---------------------------------------------------
package HTML::Form::ImageInput;
@HTML::Form::ImageInput::ISA=qw(HTML::Form::SubmitInput);

sub form_name_value
{
    my $self = shift;
    my $clicked = $self-&gt;{clicked};
    return unless $clicked;
    return if $self-&gt;{disabled};
    my $name = $self-&gt;{name};
    $name = (defined($name) &amp;&amp; length($name)) ? "$name." : "";
    return ("${name}x" =&gt; $clicked-&gt;[0],
	    "${name}y" =&gt; $clicked-&gt;[1]
	   );
}

#---------------------------------------------------
package HTML::Form::FileInput;
@HTML::Form::FileInput::ISA=qw(HTML::Form::TextInput);


sub file {
    my $self = shift;
    $self-&gt;value(@_);
}


sub filename {
    my $self = shift;
    my $old = $self-&gt;{filename};
    $self-&gt;{filename} = shift if @_;
    $old = $self-&gt;file unless defined $old;
    $old;
}


sub content {
    my $self = shift;
    my $old = $self-&gt;{content};
    $self-&gt;{content} = shift if @_;
    $old;
}


sub headers {
    my $self = shift;
    my $old = $self-&gt;{headers} || [];
    $self-&gt;{headers} = [@_] if @_;
    @$old;
}

sub form_name_value {
    my($self, $form) = @_;
    return $self-&gt;SUPER::form_name_value($form)
	if $form-&gt;method ne "POST" ||
	   $form-&gt;enctype ne "multipart/form-data";

    my $name = $self-&gt;name;
    return unless defined $name;
    return if $self-&gt;{disabled};

    my $file = $self-&gt;file;
    my $filename = $self-&gt;filename;
    my @headers = $self-&gt;headers;
    my $content = $self-&gt;content;
    if (defined $content) {
	$filename = $file unless defined $filename;
	$file = undef;
	unshift(@headers, "Content" =&gt; $content);
    }
    elsif (!defined($file) || length($file) == 0) {
	return;
    }

    # legacy (this used to be the way to do it)
    if (ref($file) eq "ARRAY") {
	my $f = shift @$file;
	my $fn = shift @$file;
	push(@headers, @$file);
	$file = $f;
	$filename = $fn unless defined $filename;
    }

    return ($name =&gt; [$file, $filename, @headers]);
}

package HTML::Form::KeygenInput;
@HTML::Form::KeygenInput::ISA=qw(HTML::Form::Input);

sub challenge {
    my $self = shift;
    return $self-&gt;{challenge};
}

sub keytype {
    my $self = shift;
    return lc($self-&gt;{keytype} || 'rsa');
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

HTML::Form - Class that represents an HTML form element

=head1 VERSION

version 6.07

=head1 SYNOPSIS

 use HTML::Form;
 $form = HTML::Form-&gt;parse($html, $base_uri);
 $form-&gt;value(query =&gt; "Perl");

 use LWP::UserAgent;
 $ua = LWP::UserAgent-&gt;new;
 $response = $ua-&gt;request($form-&gt;click);

=head1 DESCRIPTION

Objects of the C&lt;HTML::Form&gt; class represents a single HTML
C&lt;E&lt;lt&gt;formE&lt;gt&gt; ... E&lt;lt&gt;/formE&lt;gt&gt;&gt; instance.  A form consists of a
sequence of inputs that usually have names, and which can take on
various values.  The state of a form can be tweaked and it can then be
asked to provide L&lt;HTTP::Request&gt; objects that can be passed to the
request() method of L&lt;LWP::UserAgent&gt;.

The following methods are available:

=over 4

=item @forms = HTML::Form-&gt;parse( $html_document, $base_uri )

=item @forms = HTML::Form-&gt;parse( $html_document, base =&gt; $base_uri, %opt )

=item @forms = HTML::Form-&gt;parse( $response, %opt )

The parse() class method will parse an HTML document and build up
C&lt;HTML::Form&gt; objects for each &lt;form&gt; element found.  If called in scalar
context only returns the first &lt;form&gt;.  Returns an empty list if there
are no forms to be found.

The required arguments is the HTML document to parse ($html_document) and the
URI used to retrieve the document ($base_uri).  The base URI is needed to resolve
relative action URIs.  The provided HTML document should be a Unicode string
(or US-ASCII).

By default HTML::Form assumes that the original document was UTF-8 encoded and
thus encode forms that don't specify an explicit I&lt;accept-charset&gt; as UTF-8.
The charset assumed can be overridden by providing the C&lt;charset&gt; option to
parse().  It's a good idea to be explicit about this parameter as well, thus
the recommended simplest invocation becomes:

    my @forms = HTML::Form-&gt;parse(
        Encode::decode($encoding, $html_document_bytes),
        base =&gt; $base_uri,
	charset =&gt; $encoding,
    );

If the document was retrieved with LWP then the response object provide methods
to obtain a proper value for C&lt;base&gt; and C&lt;charset&gt;:

    my $ua = LWP::UserAgent-&gt;new;
    my $response = $ua-&gt;get("http://www.example.com/form.html");
    my @forms = HTML::Form-&gt;parse($response-&gt;decoded_content,
	base =&gt; $response-&gt;base,
	charset =&gt; $response-&gt;content_charset,
    );

In fact, the parse() method can parse from an L&lt;HTTP::Response&gt; object
directly, so the example above can be more conveniently written as:

    my $ua = LWP::UserAgent-&gt;new;
    my $response = $ua-&gt;get("http://www.example.com/form.html");
    my @forms = HTML::Form-&gt;parse($response);

Note that any object that implements a decoded_content(), base() and
content_charset() method with similar behaviour as L&lt;HTTP::Response&gt; will do.

Additional options might be passed in to control how the parse method
behaves.  The following are all the options currently recognized:

=over

=item C&lt;&lt; base =&gt; $uri &gt;&gt;

This is the URI used to retrieve the original document.  This option is not optional ;-)

=item C&lt;&lt; charset =&gt; $str &gt;&gt;

Specify what charset the original document was encoded in.  This is used as
the default for accept_charset.  If not provided this defaults to "UTF-8".

=item C&lt;&lt; verbose =&gt; $bool &gt;&gt;

Warn (print messages to STDERR) about any bad HTML form constructs found.
You can trap these with $SIG{__WARN__}.  The default is not to issue warnings.

=item C&lt;&lt; strict =&gt; $bool &gt;&gt;

Initialize any form objects with the given strict attribute.
If the strict is turned on the methods that change values of the form will croak if you try
to set illegal values or modify readonly fields.
The default is not to be strict.

=back

=item $form-&gt;push_input( $type, \%attr, $verbose )

This method adds additional inputs to the form.
The first argument is the type of input (e.g. hidden, option, etc.).
The second argument is a reference to a hash of the input attributes.
The third argument is optional, and will issue warnings about unknown input types.

Example:

    push_input( 'hidden', {
        name  =&gt; 'NewFormElement',
        id    =&gt; 'NewFormElementId',
        value =&gt; 'some value',
    });

=item $method = $form-&gt;method

=item $form-&gt;method( $new_method )

This method is gets/sets the I&lt;method&gt; name used for the
L&lt;HTTP::Request&gt; generated.  It is a string like "GET" or "POST".

=item $action = $form-&gt;action

=item $form-&gt;action( $new_action )

This method gets/sets the URI which we want to apply the request
I&lt;method&gt; to.

=item $enctype = $form-&gt;enctype

=item $form-&gt;enctype( $new_enctype )

This method gets/sets the encoding type for the form data.  It is a
string like "application/x-www-form-urlencoded" or "multipart/form-data".

=item $accept = $form-&gt;accept_charset

=item $form-&gt;accept_charset( $new_accept )

This method gets/sets the list of charset encodings that the server processing
the form accepts. Current implementation supports only one-element lists.
Default value is "UNKNOWN" which we interpret as a request to use document
charset as specified by the 'charset' parameter of the parse() method.

=item $value = $form-&gt;attr( $name )

=item $form-&gt;attr( $name, $new_value )

This method give access to the original HTML attributes of the &lt;form&gt; tag.
The $name should always be passed in lower case.

Example:

   @f = HTML::Form-&gt;parse( $html, $foo );
   @f = grep $_-&gt;attr("id") eq "foo", @f;
   die "No form named 'foo' found" unless @f;
   $foo = shift @f;

=item $bool = $form-&gt;strict

=item $form-&gt;strict( $bool )

Gets/sets the strict attribute of a form.  If the strict is turned on
the methods that change values of the form will croak if you try to
set illegal values or modify readonly fields.  The default is not to be strict.

=item @inputs = $form-&gt;inputs

This method returns the list of inputs in the form.  If called in
scalar context it returns the number of inputs contained in the form.
See L&lt;/INPUTS&gt; for what methods are available for the input objects
returned.

=item $input = $form-&gt;find_input( $selector )

=item $input = $form-&gt;find_input( $selector, $type )

=item $input = $form-&gt;find_input( $selector, $type, $index )

=item @inputs = $form-&gt;find_input( $selector )

=item @inputs = $form-&gt;find_input( $selector, $type )

This method is used to locate specific inputs within the form.  All
inputs that match the arguments given are returned.  In scalar context
only the first is returned, or C&lt;undef&gt; if none match.

If $selector is not C&lt;undef&gt;, then the input's name, id, class attribute must
match.  A selector prefixed with '#' must match the id attribute of the input.
A selector prefixed with '.' matches the class attribute.  A selector prefixed
with '^' or with no prefix matches the name attribute.

If $type is not C&lt;undef&gt;, then the input must have the specified type.
The following type names are used: "text", "password", "hidden",
"textarea", "file", "image", "submit", "radio", "checkbox" and "option".

The $index is the sequence number of the input matched where 1 is the
first.  If combined with $name and/or $type, then it selects the I&lt;n&gt;th
input with the given name and/or type.

=item $value = $form-&gt;value( $selector )

=item $form-&gt;value( $selector, $new_value )

The value() method can be used to get/set the value of some input.  If
strict is enabled and no input has the indicated name, then this method will croak.

If multiple inputs have the same name, only the first one will be
affected.

The call:

    $form-&gt;value('foo')

is basically a short-hand for:

    $form-&gt;find_input('foo')-&gt;value;

=item @names = $form-&gt;param

=item @values = $form-&gt;param( $name )

=item $form-&gt;param( $name, $value, ... )

=item $form-&gt;param( $name, \@values )

Alternative interface to examining and setting the values of the form.

If called without arguments then it returns the names of all the
inputs in the form.  The names will not repeat even if multiple inputs
have the same name.  In scalar context the number of different names
is returned.

If called with a single argument then it returns the value or values
of inputs with the given name.  If called in scalar context only the
first value is returned.  If no input exists with the given name, then
C&lt;undef&gt; is returned.

If called with 2 or more arguments then it will set values of the
named inputs.  This form will croak if no inputs have the given name
or if any of the values provided does not fit.  Values can also be
provided as a reference to an array.  This form will allow unsetting
all values with the given name as well.

This interface resembles that of the param() function of the CGI
module.

=item $form-&gt;try_others( \&amp;callback )

This method will iterate over all permutations of unvisited enumerated
values (&lt;select&gt;, &lt;radio&gt;, &lt;checkbox&gt;) and invoke the callback for
each.  The callback is passed the $form as argument.  The return value
from the callback is ignored and the try_others() method itself does
not return anything.

=item $request = $form-&gt;make_request

Will return an L&lt;HTTP::Request&gt; object that reflects the current setting
of the form.  You might want to use the click() method instead.

=item $request = $form-&gt;click

=item $request = $form-&gt;click( $selector )

=item $request = $form-&gt;click( $x, $y )

=item $request = $form-&gt;click( $selector, $x, $y )

Will "click" on the first clickable input (which will be of type
C&lt;submit&gt; or C&lt;image&gt;).  The result of clicking is an L&lt;HTTP::Request&gt;
object that can then be passed to L&lt;LWP::UserAgent&gt; if you want to
obtain the server response.

If a $selector is specified, we will click on the first clickable input
matching the selector, and the method will croak if no matching clickable
input is found.  If $selector is I&lt;not&gt; specified, then it
is ok if the form contains no clickable inputs.  In this case the
click() method returns the same request as the make_request() method
would do.  See description of the find_input() method above for how
the $selector is specified.

If there are multiple clickable inputs with the same name, then there
is no way to get the click() method of the C&lt;HTML::Form&gt; to click on
any but the first.  If you need this you would have to locate the
input with find_input() and invoke the click() method on the given
input yourself.

A click coordinate pair can also be provided, but this only makes a
difference if you clicked on an image.  The default coordinate is
(1,1).  The upper-left corner of the image is (0,0), but some badly
coded CGI scripts are known to not recognize this.  Therefore (1,1) was
selected as a safer default.

=item @kw = $form-&gt;form

Returns the current setting as a sequence of key/value pairs.  Note
that keys might be repeated, which means that some values might be
lost if the return values are assigned to a hash.

In scalar context this method returns the number of key/value pairs
generated.

=item $form-&gt;dump

Returns a textual representation of current state of the form.  Mainly
useful for debugging.  If called in void context, then the dump is
printed on STDERR.

=back

=head1 INPUTS

An C&lt;HTML::Form&gt; objects contains a sequence of I&lt;inputs&gt;.  References to
the inputs can be obtained with the $form-&gt;inputs or $form-&gt;find_input
methods.

Note that there is I&lt;not&gt; a one-to-one correspondence between input
I&lt;objects&gt; and E&lt;lt&gt;inputE&lt;gt&gt; I&lt;elements&gt; in the HTML document.  An
input object basically represents a name/value pair, so when multiple
HTML elements contribute to the same name/value pair in the submitted
form they are combined.

The input elements that are mapped one-to-one are "text", "textarea",
"password", "hidden", "file", "image", "submit" and "checkbox".  For
the "radio" and "option" inputs the story is not as simple: All
E&lt;lt&gt;input type="radio"E&lt;gt&gt; elements with the same name will
contribute to the same input radio object.  The number of radio input
objects will be the same as the number of distinct names used for the
E&lt;lt&gt;input type="radio"E&lt;gt&gt; elements.  For a E&lt;lt&gt;selectE&lt;gt&gt; element
without the C&lt;multiple&gt; attribute there will be one input object of
type of "option".  For a E&lt;lt&gt;select multipleE&lt;gt&gt; element there will
be one input object for each contained E&lt;lt&gt;optionE&lt;gt&gt; element.  Each
one of these option objects will have the same name.

The following methods are available for the I&lt;input&gt; objects:

=over 4

=item $input-&gt;type

Returns the type of this input.  The type is one of the following
strings: "text", "password", "hidden", "textarea", "file", "image", "submit",
"radio", "checkbox" or "option".

=item $name = $input-&gt;name

=item $input-&gt;name( $new_name )

This method can be used to get/set the current name of the input.

=item $input-&gt;id

=item $input-&gt;class

These methods can be used to get/set the current id or class attribute for the input.

=item $input-&gt;selected( $selector )

Returns TRUE if the given selector matched the input.  See the description of
the find_input() method above for a description of the selector syntax.

=item $value = $input-&gt;value

=item $input-&gt;value( $new_value )

This method can be used to get/set the current value of an
input.

If strict is enabled and the input only can take an enumerated list of values,
then it is an error to try to set it to something else and the method will
croak if you try.

You will also be able to set the value of read-only inputs, but a
warning will be generated if running under C&lt;perl -w&gt;.

=item $autocomplete = $input-&gt;autocomplete

=item $input-&gt;autocomplete( $new_autocomplete )

This method can be used to get/set the current value (if any) of C&lt;autcomplete&gt; for the input.

=item $input-&gt;possible_values

Returns a list of all values that an input can take.  For inputs that
do not have discrete values, this returns an empty list.

=item $input-&gt;other_possible_values

Returns a list of all values not tried yet.

=item $input-&gt;value_names

For some inputs the values can have names that are different from the
values themselves.  The number of names returned by this method will
match the number of values reported by $input-&gt;possible_values.

When setting values using the value() method it is also possible to
use the value names in place of the value itself.

=item $bool = $input-&gt;readonly

=item $input-&gt;readonly( $bool )

This method is used to get/set the value of the readonly attribute.
You are allowed to modify the value of readonly inputs, but setting
the value will generate some noise when warnings are enabled.  Hidden
fields always start out readonly.

=item $bool = $input-&gt;disabled

=item $input-&gt;disabled( $bool )

This method is used to get/set the value of the disabled attribute.
Disabled inputs do not contribute any key/value pairs for the form
value.

=item $input-&gt;form_name_value

Returns a (possible empty) list of key/value pairs that should be
incorporated in the form value from this input.

=item $input-&gt;check

Some input types represent toggles that can be turned on/off.  This
includes "checkbox" and "option" inputs.  Calling this method turns
this input on without having to know the value name.  If the input is
already on, then nothing happens.

This has the same effect as:

    $input-&gt;value($input-&gt;possible_values[1]);

The input can be turned off with:

    $input-&gt;value(undef);

=item $input-&gt;click($form, $x, $y)

Some input types (currently "submit" buttons and "images") can be
clicked to submit the form.  The click() method returns the
corresponding L&lt;HTTP::Request&gt; object.

=back

If the input is of type C&lt;file&gt;, then it has these additional methods:

=over 4

=item $input-&gt;file

This is just an alias for the value() method.  It sets the filename to
read data from.

For security reasons this field will never be initialized from the parsing
of a form.  This prevents the server from triggering stealth uploads of
arbitrary files from the client machine.

=item $filename = $input-&gt;filename

=item $input-&gt;filename( $new_filename )

This get/sets the filename reported to the server during file upload.
This attribute defaults to the value reported by the file() method.

=item $content = $input-&gt;content

=item $input-&gt;content( $new_content )

This get/sets the file content provided to the server during file
upload.  This method can be used if you do not want the content to be
read from an actual file.

=item @headers = $input-&gt;headers

=item input-&gt;headers($key =&gt; $value, .... )

This get/set additional header fields describing the file uploaded.
This can for instance be used to set the C&lt;Content-Type&gt; reported for
the file.

=back

=head1 SEE ALSO

L&lt;LWP&gt;, L&lt;LWP::UserAgent&gt;, L&lt;HTML::Parser&gt;

=head1 AUTHOR

Gisle Aas &lt;gisle@activestate.com&gt;

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 1998 by Gisle Aas.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</pre></body></html>